VBA – エラトステネスの篩を用いた最速素数アルゴリズムのVBA実装と高速なデータ出力

Private Function PrimeNumbers(ByVal N As Long) As Variant
    ' N以下の素数をエラトステネスの篩で検出し、配列として返す関数

    Dim i As Long, j As Long
    Dim Max As Long
    Dim Flg() As Boolean    ' 素数判定用のフラグ
    Dim Pns() As Long       ' 素数の配列
    Dim C As Long

    If N < 2 Then
        PrimeNumbers = Array() ' 2未満の場合、空の配列を返す
        Exit Function
    End If
    
    ' フラグを初期化し、全てを素数と仮定する
    ReDim Flg(1 To N)
    For i = 1 To N
        Flg(i) = True
    Next
    
    ' 1は素数ではない
    Flg(1) = False
    
    ' チェックする最大値
    Max = Sqr(N)
    
    ' エラトステネスの篩アルゴリズム
    For i = 2 To Max
        If Flg(i) Then
            For j = i + i To N Step i
                Flg(j) = False
            Next
        End If
    Next
    
    ' 素数の数を数える
    C = 0
    For i = 1 To N
        If Flg(i) Then C = C + 1
    Next
    
    ' 素数を配列にセット
    ReDim Pns(1 To C)
    C = 0
    For i = 1 To N
        If Flg(i) Then
            C = C + 1
            Pns(C) = i
        End If
    Next
    
    PrimeNumbers = Pns
End Function

Sub PnsCallTest4()
    Dim Pns As Variant
    Dim T As Single
    Dim N As Integer, i As Long
    
    T = Timer

    ' 素数配列の取得
    Pns = PrimeNumbers(1 * 10 ^ 7)
    
    Debug.Print Timer - T
    
    N = FreeFile
    ' デスクトップのtest.txtへ
    Open CreateObject("WScript.Shell").SpecialFolders("DeskTop") & "\test.txt" For Output As #N
    
    For i = 1 To UBound(Pns)
        Print #N, CStr(i); ","; CStr(Pns(i))
    Next
    Close #N
    
    Debug.Print Timer - T
End Sub

Sub PnsCallTest3()
    Dim Pns As Variant
    Dim T As Single
    
    T = Timer
    
    ' 素数配列の取得
    Pns = PrimeNumbers(82 * 10 ^ 4)
    
    Debug.Print Timer - T
    
    ' 配列をN行1列に変換してシートへ
    If UBound(Pns) >= 0 Then
        ActiveCell.Resize(UBound(Pns)).Value = Application.WorksheetFunction.Transpose(Pns)
    End If
End Sub